/*
   June 2007
   FlvPlayer 8

   Copyright © 2007 by Andrei Potorac
   andrei_potorac@yahoo.com
   All rights reserved.
*/
//************************************************************//
//  EFFECT: "FADE IN" AND "FADE OUT" IMAGES
//************************************************************//
MovieClip.prototype.fade = function(dir:String, addInteger:Number, f):Void  {
	this.step = (dir == "in") ? 0 : 100;
	delete this.onEnterFrame;
	//
	this.onEnterFrame = function():Void  {
		this.step = this._alpha;
		this.step = (dir == "in") ? this.step+addInteger : this.step-addInteger;
		this._alpha = this.step;
		if (((dir == "in") && this._alpha>=100) || ((dir == "out") && this._alpha<=0)) {
			delete this.onEnterFrame;
			if (dir == "in") {
				this._alpha = 100;
			}
			if (dir == "out") {
				this._alpha = 0;
			}
			f();
		}
	};
};
//************************************************************//
// CHANGE THE COLOR OF A MOVIECLIP
//************************************************************//
MovieClip.prototype.setColor = function(col:String):Void  {
	this.mycol = new Color(this);
	this.mycol.setRGB(col);
};
//************************************************************//
// DOT RUN
//************************************************************//
MovieClip.prototype.dotrun = function(mydottext, char) {
	this.dots = 0;
	this.dotdir = 0;
	if (char == undefined) {
		char = ".";
	}
	this.maxdot = 3;
	this.onEnterFrame = function() {
		this.dots += this.dotdir;
		if (this.dots>=this.maxdot) {
			this.dotdir = -1;
		} else if (this.dots<1) {
			this.dotdir = 1;
		}
		this.tempdots = "";
		for (dc=0; dc<this.dots; dc++) {
			this.tempdots += char;
		}
		this.txt.htmlText = mydottext+this.tempdots;
	};
};